Google Sheets se puede usar para algo más que la acumulación y organización de datos. También puede usarlo para determinar la hora actual, crear gráficos y calcular la edad usando una fecha de nacimiento. Este último se descubre mediante el uso de fórmulas y funciones integradas en Google Sheets.
![Cómo calcular la edad en las hojas de cálculo de Google a partir de la fecha de nacimiento](https://i0.wp.com/www.alphr.com/wp-content/uploads/2019/03/GS-age-from-birth-date-img.jpg?resize=696%2C320&ssl=1)
Siga este artículo para ver cómo se hace.
Determinar la edad a partir de la fecha de nacimiento en Google Sheets
Cuando usa Hojas de cálculo de Google, tiene dos formas predominantes de determinar la edad a partir de una fecha de nacimiento. Está DATEDIF , que es la opción más flexible, y YEARFRAC , la opción más sencilla. Al final del artículo, debería poder determinar no solo la edad de un solo individuo, sino también la de varios grupos de diferentes personas a la vez.
Comenzaremos con la función DATEDIF.
Cálculo de la edad en Google Sheets usando la función DATEDIF
Antes de que podamos sumergirnos en la función en sí, necesitaremos saber cómo funciona. Esto requerirá aprender la sintaxis para usar con la función DATEDIF. Cada sección que ha escrito en la Función se correlaciona con una tarea, vea estas tareas a continuación:
Sintaxis
=SIFECHA(fecha_de_inicio,fecha_de_finalización,unidad)
- fecha de inicio
- El cálculo tendrá que comenzar con la fecha de nacimiento.
- fecha final
- Esta será la fecha para concluir el cálculo. Al determinar la edad actual, este número probablemente será la fecha de hoy.
- unidad
- Las opciones de salida que consisten en: "Y", "M", "D", "YM", "YD" o "MD".
- Y: número total de años completos transcurridos entre las fechas de inicio y finalización ingresadas.
- YM - La 'M' significa meses. Esta salida muestra el número de meses después de los años transcurridos por completo para 'Y'. El número no excederá de 11.
- YD - La 'D' significa días. Esta salida muestra el número de días después de los años transcurridos por completo para 'Y'. El número no excederá de 364.
- M: el número total de meses completamente transcurridos entre las fechas de inicio y finalización ingresadas.
- MD – Como en las otras unidades, 'D' significa días. Esta salida muestra el número de días después de los meses transcurridos por completo para 'M'. No puede exceder de 30.
- D: el número total de días transcurridos por completo entre las fechas de inicio y finalización ingresadas.
El cálculo
Ahora que comprende la sintaxis que se utilizará, podemos configurar la fórmula. Como se indicó anteriormente, la función SIFECHA es la opción más flexible para determinar la edad a partir de la fecha de nacimiento. La razón de esto es que puede calcular todos los detalles de la edad en un formato de año, mes y día.
Para comenzar, necesitaremos una fecha de ejemplo para usar en la celda. Usaremos 14/7/1972 para la celda A1 . Estaremos haciendo la fórmula en la celda a la derecha, B1 , si quieres seguir para entenderlo.
Comenzaremos con la versión más básica de la fórmula para calcular la edad. Si está utilizando la sintaxis anterior para averiguar qué es qué, A1 es técnicamente la fecha de inicio , hoy será la fecha de finalización y determinaremos la edad en años usando "Y" . Es por eso que la primera fórmula que se utilizará se verá así:
=datedif(A1,today(),"Y")
Sugerencia útil: copie y pegue la fórmula directamente en B2 y presione Entrar para recibir el resultado apropiado.
Cuando se hace correctamente, el número, que indica la edad calculada, se situará en B1 como 46.
![](https://i0.wp.com/www.alphr.com/wp-content/uploads/2020/09/GS-age-by-birthdate-1.png?w=690)
Hagamos la misma fórmula solo que esta vez determinaremos la edad en meses usando "M" en lugar de "Y".
=datedif(A1,today(),"M")
El total serían 559 meses. Tiene 559 meses.
![](https://i0.wp.com/www.alphr.com/wp-content/uploads/2020/09/GS-age-by-birthdate-2.png?w=690)
Sin embargo, este número es un poco absurdo y creo que podemos reducirlo un poco usando "YM" en lugar de solo "M".
=datedif(A1,today(),"YM")
El nuevo resultado debería ser 7, que es un número mucho más manejable.
Solo para ser minuciosos, veamos cómo se verán los días usando "YD" y "MD".
=datedif(A1,today(),"YD")
=datedif(A1,today(),"MD")
Esta vez, los resultados de "YD" se muestran en B1 y el resultado de "MD" se encuentra en la celda B2.
![](https://i0.wp.com/www.alphr.com/wp-content/uploads/2020/09/GS-age-by-birthdate-3.png?w=690)
¿Lo entendiste hasta ahora?
A continuación, juntaremos todo esto en un esfuerzo por proporcionarnos un cálculo más detallado. La fórmula puede ser un poco complicada de escribir, así que simplemente copie y pegue la fórmula proporcionada en la celda B1.
La fórmula a utilizar es:
=datedif(A1,today(),"Y")&" Years "&datedif(A1,today(),"YM")&" months & "& datedif(A1,today(),"MD")&" days"
El ampersand se usa para unir cada fórmula como un eslabón de cadena. Esto es necesario para obtener el cálculo completo. Su hoja de cálculo de Google debe contener la misma fórmula que:
![](https://i0.wp.com/www.alphr.com/wp-content/uploads/2020/09/GS-age-by-birthdate-4.png?w=690)
Un cálculo completo y detallado nos ha proporcionado 46 años, 7 meses y 26 días. También puede usar la misma fórmula usando la función ArrayFormula. Esto significa que puede calcular más de una sola fecha, pero también varias fechas.
Elegimos algunas fechas al azar y las insertamos en celdas adicionales A2-A5 . Elige tus propias fechas y diviértete un poco. Para usar la función ArrayFormula, copie y pegue lo siguiente en la celda B1:
=ArrayFormula(datedif(A1:A5,today(),"Y")&" Years "&datedif(A1:A5,today(),"YM")&" months & "& datedif(A1:A5,today(),"MD")&" days")
Estos son los resultados:
![](https://i0.wp.com/www.alphr.com/wp-content/uploads/2020/09/GS-age-by-birthdate-5.png?w=690)
Ahora, supongamos que desea separar cada parte de la fecha en su propia pequeña columna ordenada por el bien de la organización. En Hojas de cálculo de Google, agregue su fecha de inicio (la fecha de nacimiento) en una columna y la fecha de finalización en otra. Elegimos la celda B2 para start_date y C2 para end_date en mi ejemplo. Mis fechas se correlacionan con los nacimientos y muertes recientes de las celebridades Burt Reynolds, Johnny Cash y Luke Perry.
![](https://i0.wp.com/www.alphr.com/wp-content/uploads/2020/09/GS-age-by-birthdate-7-300x109-1.png?w=690)
Como se muestra, la columna A es el nombre de la persona, la columna B contiene la fecha de inicio y la C la fecha de finalización. Ahora, agregaremos cuatro columnas más a la derecha. Uno para cada uno de "Y", "YM", "YD" y una combinación de los tres. Ahora solo tienes que agregar las fórmulas correctas a cada fila para cada celebridad.
Burt Reynolds:
=DATEDIF(B2,C2,"Y")
Cambie 'Y' a la columna correspondiente que está tratando de calcular.
Johnny Cash:
=DATEDIF(B3,C3,"Y")
Cambie 'Y' a la columna correspondiente que está tratando de calcular.
Lucas Perry:
=DATEDIF(B4,C4,"Y")
Cambie 'Y' a la columna correspondiente que está tratando de calcular.
Para obtener la fórmula JOINED, deberá usar una ArrayFormula tal como lo hicimos anteriormente en este artículo. Puede agregar palabras como Años para indicar los resultados de los años colocándolo después de la fórmula y entre paréntesis.
=ArrayFormula(datedif(B2,C2,"Y")&" Years "&datedif(B2,C2,"YM")&" months & "& datedif(B2,C2,"MD")&" days")
La fórmula anterior es por celebridad. Sin embargo, si desea eliminarlos todos de una sola vez, copie y pegue la siguiente fórmula en la celda G2 :
=ArrayFormula(datedif(B2:B4,C2:C4,"Y")&" Years "&datedif(B2:B4,C2:C4,"YM")&" months & "& datedif(B2:B4,C2:C4,"MD")&" days")
Su hoja de cálculo de Google debería terminar luciendo algo como esto:
![](https://i0.wp.com/www.alphr.com/wp-content/uploads/2020/09/GS-age-by-birthdate-6.png?w=690)
Bastante ordenado, ¿eh? Realmente es así de simple cuando se usa la función DATEDIF. Ahora, podemos pasar a usar la función YEARFRAC.
Cálculo de la edad en Google Sheets usando la función YEARFRAC
La función YEARFRAC es simple para resultados simples. Es directo al grano y proporciona un resultado final sin todos los resultados adicionales adicionales durante años, meses y días.
Aquí hay una fórmula básica, aplicable a una sola celda:
=int(YEARFRAC(A1,today()))
Agregará la fecha de nacimiento a la celda A1 y pegará la fórmula en B1 para obtener el resultado. Usaremos la fecha de nacimiento 11/04/1983 :
![](https://i0.wp.com/www.alphr.com/wp-content/uploads/2020/09/GS-age-by-birthdate-9.png?w=690)
El resultado es 35 años de edad. Simple, como cuando se usa la función DATEDIF para una sola celda. Desde aquí podemos pasar a usar YEARFRAC dentro de una ArrayFormula. Esta fórmula es más útil para usted cuando necesita calcular la edad de grupos grandes como estudiantes, miembros de la facultad, miembros del equipo, etc.
Tendremos que agregar una columna de diferentes fechas de nacimiento. Para esto, usaremos la columna B ya que A se usará para los nombres de las personas. La columna C se utilizará para los resultados finales.
![](https://i0.wp.com/www.alphr.com/wp-content/uploads/2020/09/GS-age-by-birthdate-8-300x164-1.png?w=690)
Para completar la edad en la columna contigua, necesitaremos usar la siguiente fórmula:
=ArrayFormula(int(yearfrac(B2:B8,today(),1)))
Coloque la fórmula anterior en la celda C2 para obtener los resultados.
Si prefiere continuar con una columna completa y prefiere no molestarse en averiguar dónde termina, puede agregar una ligera variación a la fórmula. Agregue IF y LEN hacia el comienzo de ArrayFormula así:
=ArrayFormula(if(len(B2:B),(int(yearfrac(B2:B,today(),1))),))
Esto calculará todos los resultados dentro de esa columna a partir de B2 .
Hojas de cálculo de Google y fechas de nacimiento
Google Sheets tiene muchas funciones integradas útiles que se pueden usar para hacer la vida más fácil. Ya sea que se trate de una función para sumar rápidamente valores en una fila/columna o para calcular la edad de alguien, Hojas de cálculo de Google lo tiene cubierto.
0 Comentarios